[#Part : VCH Narration]
Option : MS VCHNarrHistory : @@IsPayment
[!Part : MS VCHNarrHistory]
Add : Line : AtEnd : MS VCHNarrHistory
[Line : MS VCHNarrHistory]
Field : Medium Prompt,MS VCHNarrHistory
Local : Field : Medium Prompt : Info : If $$InCreateMode Then "Narration History :" Else ""
Local : Field : Medium Prompt : Width : 15% Page
[Field : MS VCHNarrHistory]
Use : Name Field
Set as : $$Value
Storage : MSVCHNarrHistory
Style : Normal
Width : 46
Invisible : Not($$InCreateMode)
Skip : Not($$InCreateMode)
Table : NarrHistoryColl,endoflist
ShowTable : Always
Key : Narration
;---------------------------------
[#Part : VCH Narration]
Option : MS VCHNarrTemp : @@IsPayment
[!Part : MS VCHNarrTemp]
Add : Line : AtEnd : MS VCHNarrTemp
[Line : MS VCHNarrTemp]
Field : Medium Prompt,MS VCHNarrTemp
Local : Field : Medium Prompt : Info : If $$InCreateMode Then "Master Narrations :" Else ""
Local : Field : Medium Prompt : Width : 15% Page
[Field : MS VCHNarrTemp]
Use : Name Field
Set as : $$Value
Storage : MSVCHNarrTemp
Style : Normal
Width : 42
Invisible : Not($$InCreateMode)
Skip : Not($$InCreateMode)
Table : MyNarrationCollection,endoflist
ShowTable : Always
Key : Narration
;---------------------------------
[#Part: VCH Narration]
Option : MS VCHNarrMonth : @@IsPayment
[!Part : MS VCHNarrMonth]
Add : Line : AtEnd : MS VCHNarrMonth
[Line : MS VCHNarrMonth]
Field : Medium Prompt,MS VCHNarrMonth
Local : Field : Medium Prompt :Info : If $$InCreateMode Then "Add Month/Period :" Else ""
Local : Field : Medium Prompt :Width : 15% Page
[Field : MS VCHNarrMonth]
Use : Name Field
Set as : $$Value ;If $$InCreateMode Then $MSVCHNarrMonth Else ""
Storage : MSVCHNarrMonth
Style : Normal
Max : 30
Width : 30
Invisible : Not($$InCreateMode)
Skip : Not($$InCreateMode)
Control : NarrControl : @@NarBoth
;;;====================================================================================================
[System : Formula]
NarHst : IF $$IsEndOfList:#MSVCHNarrHistory Then "" Else #MSVCHNarrHistory
NarTmp : IF $$IsEndOfList:#MSVCHNarrTemp Then "" Else #MSVCHNarrTemp
NarMth : IF $$IsEmpty:#MSVCHNarrMonth Then "" Else #MSVCHNarrMonth
NarBoth : If (Not $$IsEndOfList:#MSVCHNarrHistory AND Not $$IsEndOfList:#MSVCHNarrTemp) Then "Yes" Else "No"
NarCombine : If ($$IsEndOfList:#MSVCHNarrHistory AND $$IsEndOfList:#MSVCHNarrTemp) Then @@NarMth Else If Not $$IsEmpty:#MSVCHNarrMonth Then (@@NarHst + @@NarTmp + " - " + @@NarMth) Else (@@NarHst + @@NarTmp)
NarrControl : "Both Narrations Selected!!" + $$NewLine + $$NewLine + "Select Only One Narration"
;;;====================================================================================================
[#Field: VCH Narration]
Use : Voucher Narration Field
Lines : 2
Storage : Narration
Set as : If $$InCreateMode Then @@NarCombine Else $Narration
Width : 50% Screen
Key : PrevVchNarration, PrevLedNarration
Set Always : Yes
;;;====================================================================================================
[#Menu: Accounts Info.]
Add : Item : after : @@locCostCentres : Narration : alter : CMP NarrationReport
[#Part: CMP AccFeat Left]
Add : Line : CMP EnablePortDestTable
[Line: CMP EnablePortDestTable]
Field : Medium Prompt, CMPEnableNarrationTable
Local : Field : Medium Prompt : Info : "Enable Predefined Narration ? "
Space Top : 1
[Field: CMPEnableNarrationTable]
Use : Logical Field
Storage : Enableprenarration
Set as : If $$IsEmpty:$$Value then "No" else $$Value
;;;--------------------------------------
[Report: CMP NarrationReport]
Form : CMP NarrationForm
Object : company
[Form: CMP NarrationForm]
Part : CMP Narration PartTitle, CMP Narration PartDetails
[Part: CMP Narration PartTitle]
Line : CMP Narration LineTitle
Border : thin bottom
[Line: CMP Narration LineTitle]
Field : Long Prompt
Local : Field : Long Prompt : Style : Normal Bold
Local : Field : Long Prompt : Info : "Enter Your Master Narrations"
Local : Field : Long Prompt : Width : 60% Screen
Local : Field : Long Prompt : Align : Center
[Part: CMP Narration PartDetails]
Line : narration title,CMP Narration LineDetails
Repeat : CMP Narration LineDetails : MydbNarration
BreakOn : $$IsEmpty:$PreNarration
Height : 33
Width : 60% Screen
Scroll : Vertical
CommonBorder: Yes
[Line:narration title]
Fields : srno,narration title
Border : thin bottom
[Field:srno]
Use : MultiSNo Title
Width : 6
[Field:narration title]
Set as : "For Ledger Standard Predefined Narrations"
Style : Normal Bold
Align : Center
[Line: CMP Narration LineDetails]
Field : number, CMP ForLedgerField, CMP Narration NameField
[Field:number]
Use : Multi SNo
Width : 6
Style : Normal
Align : Center
[Field: CMP ForLedgerField]
Use : Short Name Field
Storage : ForLedger
Style : Normal
Align : Center
Border : Thin Left
Width : 12% Screen
Lines : 1
Max : 3
[Field: CMP Narration NameField]
Use : Short Name Field
Storage : PreNarration
Style : Normal
Border : Thin Left
Width : 51% Screen
Lines : 1
Max : 36
;;;====================================================================================================
[Collection: MyNarrationCollection]
Type : MydbNarration: Company
Childof : ##SVCurrentCompany
Filter : ForLedgerFilt ;New entry for Ledger Filter
Format : $PreNarration,36
Title : Predifined Narrations
Sort : Default : $PreNarration
;;;--------------------------------------
[Collection : NarrHistoryColl]
Type : Vouchers : Ledger
Child Of : @@Children
Filter : VchTypeFilt
Format : $Narration,46
Title : Narration History of Selected Ledger & Voucher
Fetch : Narration
Sort : Default : $Narration
;;;--------------------------------------
[System : Formula]
Children : If Not $$IsEmpty:$$BaseOwner:#ACLSLed Then $$BaseOwner:#ACLSLed Else $$BaseOwner:#VCHParticulars
VchTypeFilt : $VoucherTypeName = ##SVVOUCHERTYPE
; ;New entry for Ledger Filter
ForLedgerFilt : $$StringPart:$ForLedger:0:3 = $$StringPart:($Narration:ledger:#ACLSLed):0:3 ; Set Notes in Ledger Master & ForLedger-Filter in Narration-Table accordingly
;;;====================================================================================================
[Key : narration]
Key : ALT + C
Action: Alter : CMP NarrationReport
;;;====================================================================================================
;;;====================================================================================================
.jpg)
hello sir, good evening
जवाब देंहटाएंpls help sir
here is a code for for auto discount entry which is showing error pls help to correct it
thanx in advance
[#Form:Day Book]
Add:Button:Auto Discount Journal Entry Button
[Button:Auto Discount Journal Entry Button]
Key:Ctrl+3
Title:"Pass discount?"
Action:Call:Auto Discount Journal Entry Function
Mode: Display
Scope: Selected Lines
Inactive: $$NumLinesInScope = 0
[Function:Auto Discount Journal Entry Function]
Variable:RCPCounter:Number
Variable:RCPADJE Date:Date
Variable:RCPADJE Discount Ledger:String
Variable:RCPADJE Discount Amt:Amount
Variable:RCPADJE Party Ledger:String:""
Variable:RCPADJE Reference No:String:""
Variable:RCPDBtempVchMSTID:String
000:Walk Collection:RCPDBSelectedVocuhers
010:Set: RCPDBtempVchMSTID:"ID:"+$$String:$MasterID
015:If:$RCPDiscAutoJournYNoFldStore="No"
;;Modifying the User Defined Object/Field whcih prevent from duplication of discount. I have created a user defined field in Sales voucher.
018:Modify Object:RCPDiscAutoJournYNoFldStore[].RCPDiscAutoJournYNoFldStore:($$string:"Yes")
020:Set:RCPADJEDate:$Date
;;Choosing the right discount Ledger Based on Party Group, Here I am using different discount ledger for different groups
030:Set:RCPADJEDiscountLedger:If ($Parent:Ledger:$PartyLedgerName)="Jabal Akthar Debtors" Then $$LocaleString:"Jabal Discount Allowed" Else $$LocaleString:"Cash Discount"
;;$RCPAgentVCHCommissionAmt is the User defined Discount Amount. I have defined the calculations in sales voucher.
040:Set:RCPADJEDiscountAmt:$RCPAgentVCHCommissionAmt
050:Set:RCPADJEPartyLedger:$PartyLedgerName
060:Set:RCPADJEReferenceNo:$VoucherNumber
action:070:New Object:Voucher
action:080:Set Value:Date:##RCPADJEDate
action:090:Set Value:VoucherTypeName:$$VchTypeJournal
action:100:Set Value:Narration:$$LocaleString:"Hidden Commission"
action:110:Insert Collection Object:AllLedgerEntries
action:120:Set Value:LedgerName:##RCPADJEDiscountLedger
action:130:Set Value:Is Deemed Positive : "Yes"
action:140:Set Value:Amount:$$Negative:##RCPADJEDiscountAmt
action:150:Insert Collection Object:AllLedgerEntries
action:160:Set Value:LedgerName:##RCPADJEPartyLedger
action:170:Set Value:Is Deemed Positive : "No"
action:180:Set Value:Amount:##RCPADJEDiscountAmt
action:190:INSERT COLLECTION OBJECT : BillAllocations
action:200: SET VALUE : BillType : $$SysName:AgstRef
action:210: SET VALUE : Name : ##RCPADJEReferenceNo
action:220: SET VALUE : Amount : ##RCPADJEDiscountAmt
action:230: SET TARGET : ...
action:240: SET TARGET : ..
action:250: SET VALUE : PersistedView : ##SVViewName
action:260: CREATE TARGET
0265:End If
290:End Walk
OK. Let me check it.
हटाएंhello sir,i am eagerly waiting for your reply
जवाब देंहटाएंHello,
जवाब देंहटाएंI am working on existing projects i.e. why could not get time to check the code.
Please check my Channel and there you will get Idea about your query
https://www.youtube.com/channel/UCytrmo9IC-3bULlhKpUHIpg
hello dir
जवाब देंहटाएंRajeev Sir
जवाब देंहटाएंNarration History TDL is good but not Working in Tally Prime 4.1
Giving Error in
[#Menu: Accounts Info.]
Please Check & UPDATE.
Thanks